Is there a way to periodically automatically backup any document?

Question

I want to automatically save a copy of several important documents I am working on and keep all versions, not just the last one or the last two etc. Most of the documents are Word documents but not all. I am happy to pay for the software or service but have not been able to find anything that does this. There are lots of options to save the last your work as you are working but they all overwrite the last document. I do not want to do this. I need to maintain all versions of the document.

Answer 1

This will copy all .doc and.docx files from the current user's Documents folder to Documents\Backup

If the file name already exists, it adds a padded number to the end of the file name, MyFile0001.doc, MyFile0002.doc, etc. This way they will sort oldest to newest



It only copies new files, or files that have been changed since the last backup. It determines this based on the archive bit. If you run other backup programs, they may reset that bit when they make a backup; if so, this program would skip that version.

You can do it based on the modified date, but that gets a bit more complex.



Not sure if it will copy files that are open in Word, don't have Word on this system at the moment to test.

If you need help setting up a scheduled task, drop me a line. You can set it to run every day, or every 5 minutes for that matter.



Edit: Forgot to exclude the backups folder if it was a subfolder of the Source and found a couple typos, so copy/download again



Pastebin link - http://pastebin.com/gWg5x1Vt



@Echo Off

SetLocal EnableDelayedExpansion

:: Copies files from Source to Destination checking for duplicate names.

:: Filess with the same name will be given a padded, numbered, suffix

:: Uses the Archive bit to determine if a file should be copied.

Set _Source=%Userprofile%\Documents

Set _Dest=%Userprofile%\Documents\Backups

Set _Exts=*.doc *.docx

If Not Exist "%_Dest%" MD "%_Dest%"

:: copy files

PushD "%_Source%"

For /F "Delims=" %%I in ('Dir %_Exts% /A-DA /B /S 2^>Nul^|Findstr /I /V /C:"%_Dest%"') Do (

Call :_Dupcheck "%%~I"

Echo F|Xcopy "%%I" "%_Dest%\!_Newname!" /M /CHIRY>Nul

)

PopD

Goto :EOF

:::::::::::::::::::::::::::::::::::::::::::::::::::::

:: Subroutines

:::::::::::::::::::::::::::::::::::::::::::::::::::::

:_DupCheck

Set _FN=%~n1

Set _FE=%~x1

Set _Count=0

Set _Extra=

Set _Newname=%_FN%%_FE%

:_Loop

If Exist "%_Dest%\%_FN%%_Extra%%_FE%" (

Set /A _Count+=1

Set _DupNum=0000!_Count!

Set _DupNum=!_DupNum:~-4!

Set _Extra=!_DupNum!

Goto _Loop

)

Set _Newname=%_FN%%_Extra%%_FE%

Answer 2

The best backup plan is to periodically (weekly or monthly) backup the entire HD to another HD. Since the entire HD is backed up, if you have a malware or virus infection, you can restore to a date prior to the infection. Sometimes this is the only way to cure things without reinstalling the operating system and all your programs. You can restore an image and be back in operation in less than an hour. It can take you days to reinstall everything and get the computer back to the way it was if you do not have a full backup. I would still backup important documents to a thumb drive. You need more than 2 copies. After all this is an insurance plan.



Now, what software and hardware do you need.



For software I use Acronis True Image. http://www.acronis.com/homecomputing/products/trueimage/ There is also free software Paragon and Easeus: http://www.paragon-software.com/free/db.html http://tinypic.com/view.php?pic=34y9oo4&s=6. The free software has many but not all of the features of Acronis.



For hardware, I use a 1 TB Passport drive. https://www.google.com/search?q=passport+hd&ie=utf-8&oe=utf-8&aq=t&rls=org.mozilla:en-US:official&client=firefox-a These drives are under $100.



For more info on how to do this, see this site: http://www.ugr.com/nl0804.html



EDIT: I forgot to mention that the main feature that Acronis has that the other two programs lack, is automatic backups. As long as your backup drive is connected, this process can be completely automated.

Answer 3

Macs do that... I don't think theres software on PC that does this.